Tutorial

Les envois d'emails

On peut très simplement en Rebol envoyer un email avec l'instruction send
Voici un premier exemple d'envoi d'un email. On définit une variable de type Email! et on envoi un texte. Le texte se trouve dans le corps du message et dans le sujet.

rebol
[ 
  Sujet: "Utilisation des Emails"
  Auteur: "RebolZone"
  Version: 1.0.0
  Commentaires: "Utilisation de la fonction send"
]

emailDestinataire: zadmin@xyz.com
print type? emailDestinataire	; le type de la variable est email!

; Envoi de l'email
send emailDestinataire "Ceci est un test email depuis Rebol"

input
quit

On peut également envoyer un message à plusieurs destinataires en utilisant une variable de type block! L'exemple suivant montre comment envoyer le contenu d'un fichier texte avec read. Attention, ce n'est pas une pièce jointe. La présence d'un fichier déclenche l'envoi de ce fichier, ou l'envoi d'un message d'erreur.

rebol
[ 
  Sujet: "Utilisation des Emails"
  Auteur: "RebolZone"
  Version: 1.0.0
  Commentaires: "Utilisation de la fonction send avec plusieurs destinataires"
]

; Les destinataires, utilisation d'un block
emailDestinataire: [zadmin@xyz.com yadmin@xyz.com]

; Définition du fichier résultat
ficLog: %traceprg.log

; test si le fichier existe pour envoi
either exists? ficLog 
[
	send emailDestinataire read ficLog ;Envoi du contenu du fichier
] 
[
	send emailDestinataire "Erreur pas de fichier Log ..."
]
input
quit

Rebol fournit une interface permettant de gérer les entêtes d'email. Dans la console Rebol, en tapant probe system/standard/email on obtient le résultat suivant :

  make object! [
    To: none
    CC: none
    BCC: none
    From: none
    Reply-To: none
    Date: none
    Subject: none
    Return-Path: none
    Organization: none
    Message-Id: none
    Comment: none
    X-REBOL: "1.2.1.3.1 http://WWW.REBOL.COM"
    MIME-Version: none
    Content-Type: none
    Content: none
]

On a donc un objet permettant de gérer l'entête de l'email. L'exemple suivant montre comment ajouter un sujet à notre email avec le raffinement /header de l'instruction send.

rebol
[ 
  Sujet: "Utilisation des Emails"
  Auteur: "RebolZone"
  Version: 1.0.0
  Commentaires: "Utilisation d'un sujet"
]

; Destinataire
emailDestinataire: zadmin@xyz.com

; Définition du fichier résultat
ficLog: %traceprg.log

; Définition de l'entete de l'Email
emailEntete: make system/standard/email [Subject: "Test de l'entête"]

; test si le fichier existe pour envoi
either exists? ficLog 
[
	send/header emailDestinataire read ficLog emailEntete ;Envoi du contenu du fichier
] 
[
	send/header emailDestinataire "Erreur pas de fichier Log ..." emailEntete
]
; Affichage de notre instance
probe emailEntete
input
quit
   

On peut par le même principe définir les destinataires en copie (CC), les copies cachées (BCC) ...

Bientôt nous verrons comment lire des emails.