Tutorial VID

Les zones de saisie de texte Deux instructions permettent de créer des zones de saisie de texte : field (champ de saisie) et area (Zone de saisie, multilignes).
Quelques exemples :

rebol
[

title: "Les zones de saisie de texte [RebolZone]"
]

view layout [
	; Couleur de fond  (un violet clair), on peut utiliser un mot red, blue ...
	backcolor 159.96.130

	field   	; Création d'une zone de saisie
	field 300	; Création d'une zone de saisie de 300 pixels de long

	; Création d'une aréa bleue, nommée montexte
	montexte: area 300x300 wrap 185.0.185 {vous pouvez saisir un long texte ici ...}

	;Affichage de la valeur de l'aréa
	button "Vérification" [alert montexte/text]

	; création d'un bouton Quitter
	 button "Quit" [quit] 
]

Résultat :

On peut également définir les attributs de chaque zones de saisie : taille de police (font-size), couleur du texte (font-color),
la couleur du fond de la zone, italique, gras, souligné, le type de font (font-name).
La couleur du fond de la zone qui est active (focus) est jaune par défaut.

  rebol
  [
  title: "Les zones de saisie de texte [RebolZone]"
  ]

  view layout [
	; Couleur de fond de la fenêtre
	backcolor 103.88.109

	Label "RebolZone" 5.130.159 font-size 24 ;un label
	field 400 italic bold font-color red 177.207.206; Création d'une zone de saisie en italic, rouge avec fond bleu clair

	field 300 font-size 22 font-color blue; Création d'une zone de saisie de 300 pixels de long, police 22

	; Création d'une aréa bleue, nomméee montexte,  chargée avec fichier c:/tmp/test.css
	montexte: area 400x200 wrap font-color blue font-name font-fixed  read %/c/tmp/test.css

	; création d'un bouton Quitter
	 button "Quit" [quit] 
  ]
  

L'exemple ci-dessus charge l'aréa à partir d'un fichier, on peut également mentionner un fichier sur le Web (URL) :

  montexte: area 400x200 wrap font-color blue font-name font-fixed read http://rebolzone.free.fr/index.php
  

Les types de fontes (font-name) sont : font-sans-serif (par défaut), font-serif, font-fixed.

On peut également saisir un mot de passe masqué, voici un exemple où l'on utilise l'argument hide pour préciser que la saisie sera masquée. On utilise également across et return pour aligner un label avec un champ. Le mot passe peut être récupéré avec /data (mavariable/data) alors que le nom de l'utilisateur est récupéré avec /text (user/text).

  rebol
  [
  title: "Mot de passe"
  ]

  view layout [
	; Couleur de fond de la fenêtre
	backcolor 103.88.109
	
	across

	Label "RebolZone" 5.130.159 font-size 24
	return

	label "Veuillez vous identifier : "
	return

	label "Utilisateur"
	user: field 100
	return

	label "Mot de passe"
	pwd: field 100 hide
	return

	button "Ok" [alert [pwd/data] ]	; Affichage du mot de passe saisi
	button "Quitter" [quit] 
]